;;; hook to catch separate lines of input and concatenate them, then
;;; send them to the socket when you type . on a line by itself
;;; (zwrite mode) ... /zwrite on and /zwrite off toggle functionality
;;; jsm  08/30/1998

/def -h"SEND *" sendcatch_hook = \
	/if (!zstatus) /send %* %; \
	/elseif ({*} =/ '.') \
		/send %catch_message %; \
		/unset catch_message %; \
	/elseif (!(strlen(catch_message))) \
		/set catch_message %* %; \
		/echo -p @{u}%% Entering zwrite mode. \
			Type '.' to send.@{n} %; \
	/else \
		/set catch_message $[strcat(catch_message, ' ', {*})] %; \
	/endif

/def zwrite = \
	/if     ({*} =/ 'on')   /zwrite_on %; \
	/elseif ({*} =/ 'off')  /zwrite_off %; \
	/elseif ({*} =/ 'kill') /zwrite_kill %; \
	/else /echo %% zwrite: invalid option "%*". %; \
		/echo %% valid options are: on off kill %; \
	/endif

/def zwrite_on = \
	/echo -p @{hu}%% Attention: zwrite mode enabled! \
		Type '/zwrite off' to disable.@{n} %; \
	/set zstatus 1

/def zwrite_off = \
	/echo -p @{hu}%% Attention: zwrite mode disabled! \
		Type '/zwrite on' to reenable.@{n} %; \
	/set zstatus 0

/def zwrite_kill = \
	/echo -p @{huCred}%% Attention: zwrite mode killed! \
		Reload your config files or restart tf to reenable.@{n} %; \
	/unset zstatus %; \
	/undef sendcatch_hook %; \
	/purge zwrite*

/zwrite_on